Замените табуляцию пробелами в vim

Ответ 1

IIRC, что-то вроде:

set tabstop=2 shiftwidth=2 expandtab

должен сделать трюк. Если у вас уже есть вкладки, а затем следуйте за ним с помощью хорошего глобального RE, чтобы заменить их двойными пробелами.

Ответ 2

После того, как вы добавили расширение в соответствии с другими ответами, чрезвычайно удобный способ конвертировать существующие файлы в соответствии с вашими новыми настройками:

:retab

Он будет работать с текущим буфером.

Ответ 3

Try

set expandtab

для мягких вкладок.

Чтобы исправить уже существующие вкладки:

:%s/\t/  /g

Я использовал два пробела, так как вы уже установили tabstop в 2 пробела.

Ответ 4

Это сработало для меня:

вы можете видеть вкладки с первого раза:

:set list

затем, чтобы заменить вкладки, сделайте следующее:

:set expandtab

то

:retab

теперь все вкладки заменены пробелами вы можете вернуться к обычному просмотру следующим образом:

:set nolist

Ответ 5

gg=G будет повторно указывать весь файл и удаляет большинство, если не все вкладки, которые я получаю в файлах от сотрудников.

Ответ 6

Добавьте следующие строки в ваш .vimrc

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

Откройте файл в vim и нажмите F2 Вкладки будут преобразованы в 4 пробела, и файл будет сохранен автоматически.

Ответ 7

Если вы хотите, чтобы ваш \t равнялся 8 пробелам, рассмотрите настройку:

   set softtabstop=2 tabstop=8 shiftwidth=2

Это даст вам два пробела за <TAB>, но фактический \t в вашем коде по-прежнему будет отображаться как 8 символов.

Ответ 8

первый поиск вкладок в вашем файле:/^ I : установить expandtab : Retab

будет работать.

Ответ 9

expand это утилита Unix для преобразования табуляции в пробелы. Если вы не хотите ничего set в vim, вы можете использовать команду оболочки из vim:

:!% expand -t8

Ответ 10

Это заставило меня работать:

:set tabstop=2 shiftwidth=2 expandtab | retab

Ответ 11

В этой статье есть отличный vimrc script для обработки вкладок + пробелов и преобразования между ними.

Эти команды предоставляются:

Space2Tab Преобразование пробелов в вкладки, только в отступы.

Tab2Space Преобразуйте вкладки в пробелы только в отступы.

RetabIndent Выполнить Space2Tab (если установлен параметр 'expandtab') или Tab2Space (в противном случае).

Каждая команда принимает аргумент, указывающий количество пробелов в столбце вкладки. По умолчанию используется параметр "tabstop".

Источник: http://vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

Это помогло мне немного больше, чем ответы здесь, когда я впервые пошел искать решение.