Чтобы получить приглашение, которое указывает Git -branch в Zsh

Ответ 1

__git_ps1 - от git -completion.bash. В zsh вы, вероятно, должны предоставить свою собственную функцию для определения текущей директории git. Существует несколько сообщений о git prompt для zsh.

Вам просто нужно:

• функция для указания имени ветки
• включить приглашение командной строки
• добавить функцию в приглашение

Например

git_prompt() {
 ref=$(git symbolic-ref HEAD | cut -d'/' -f3)
 echo $ref
}
setopt prompt_subst
PS1=$(git_prompt)%#
autoload -U promptinit
promptinit

Обновление: используйте модуль zsh vcs_info вместо git_prompt()

setopt prompt_subst
autoload -Uz vcs_info
zstyle ':vcs_info:*' actionformats \
    '%F{5}(%f%s%F{5})%F{3}-%F{5}[%F{2}%b%F{3}|%F{1}%a%F{5}]%f '
zstyle ':vcs_info:*' formats       \
    '%F{5}(%f%s%F{5})%F{3}-%F{5}[%F{2}%b%F{5}]%f '
zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat '%b%F{1}:%F{3}%r'

zstyle ':vcs_info:*' enable git cvs svn

# or use pre_cmd, see man zshcontrib
vcs_info_wrapper() {
  vcs_info
  if [ -n "$vcs_info_msg_0_" ]; then
    echo "%{$fg[grey]%}${vcs_info_msg_0_}%{$reset_color%}$del"
  fi
}
RPROMPT=$'$(vcs_info_wrapper)'

Ответ 2

Вот расширенный запрос git для zsh: zsh-git-prompt.

Ответ 3

Ответ на ko-dos велик, но я предпочитаю немного больше git подсказки, чем тот, который он использует. В частности, я хочу, чтобы в самой подсказке были представлены статичные, неустановленные и необработанные уведомления о файлах. Используя его ответ и примеры zsh vcs_info, я придумал следующее:

setopt prompt_subst
autoload -Uz vcs_info
zstyle ':vcs_info:*' stagedstr 'M' 
zstyle ':vcs_info:*' unstagedstr 'M' 
zstyle ':vcs_info:*' check-for-changes true
zstyle ':vcs_info:*' actionformats '%F{5}[%F{2}%b%F{3}|%F{1}%a%F{5}]%f '
zstyle ':vcs_info:*' formats \
  '%F{5}[%F{2}%b%F{5}] %F{2}%c%F{3}%u%f'
zstyle ':vcs_info:git*+set-message:*' hooks git-untracked
zstyle ':vcs_info:*' enable git 
+vi-git-untracked() {
  if [[ $(git rev-parse --is-inside-work-tree 2> /dev/null) == 'true' ]] && \
  [[ $(git ls-files --other --directory --exclude-standard | sed q | wc -l | tr -d ' ') == 1 ]] ; then
  hook_com[unstaged]+='%F{1}??%f'
fi
}


precmd () { vcs_info }
PROMPT='%F{5}[%F{2}%n%F{5}] %F{3}%3~ ${vcs_info_msg_0_} %f%# '

Это создает приглашение, которое имитирует раскрашенный вывод git status -s (который может быть настроен в вашем файле .gitconfig). Изображение, возможно, наиболее полезно здесь:

По сравнению с git status -s:

Если вам не нравится цветной вывод или вы предпочитаете какую-либо другую конструкцию символов или подсказок, просто измените значения stagedstr, unstagedstr и hook_com[unstaged] в приведенном выше коде.

Ответ 4

Спасибо за ссылки!

Я сделал следующее приглашение на их основе

     # get the name of the branch we are on
     git_prompt_info() { 
         git branch | awk '/^\*/ { print $2 }'
     }
     get_git_dirty() { 
       git diff --quiet || echo '*'
     }

     autoload -U colors
     colors     
     setopt prompt_subst

     PROMPT='%{$fg[blue]%}%c %{$fg_bold[red]%}$(git_prompt_info)$(get_git_dirty)%{$fg[blue]%} $ %{$reset_color%}'                                           

     RPROMPT='%{$fg[green]%}%1(j.%j.)'        

Пожалуйста, предложите любые улучшения.

Ответ 5

Я просто переделал мой, так как у нас есть длинные названия веток на работе Этот будет усечен с помощью многоточия, если в нем более 35 символов.

parse_git_branch() {
    git_status="$(git status 2> /dev/null)"
    pattern="On branch ([^[:space:]]*)"
    if [[ ! ${git_status} =~ "(working (tree|directory) clean)" ]]; then
        state="*"
    fi
    if [[ ${git_status} =~ ${pattern} ]]; then
      branch=${match[1]}
      branch_cut=${branch:0:35}
      if (( ${#branch} > ${#branch_cut} )); then
          echo "(${branch_cut}…${state})"
      else
          echo "(${branch}${state})"
      fi
    fi
}

setopt PROMPT_SUBST
PROMPT='%{%F{blue}%}%9c%{%F{none}%}$(parse_git_branch)$'

(Я смущен тем, как я горжусь этим.)

Ответ 6

Многие из этих решений показались мне медленными, когда я нажимал клавишу возврата, поэтому здесь базовый и быстрый вариант:

parse_git_branch() {
    git branch 2> /dev/null | sed -e '/^[^*]/d' -e 's/* \(.*\)/ (\1)/'
}

setopt PROMPT_SUBST
PROMPT='%9c%{%F{green}%}$(parse_git_branch)%{%F{none}%} $ '

Вы получите приглашение, которое выглядит следующим образом: ~/dev/project (feature-branch) $